games/mini-comps/mini-comp/inherit.inf

Constant Story "INHERIT!";
Constant Headline "^An Interactive Snippet from my Hypothetical Interactive
 Mini-Comp entry.^(c) 1998 by Gunther Schmidl.^";

Constant max_score = 600;
Constant amusing_provided;

Include "Parser";
Include "VerbLib";

Object BlankRoom "(Inform library)"
 with
  description "** Library Error 11 (24,0) **",
  each_turn
  [;
   switch(++self.number)
   {
    1:
     "^Odd. Something seems wrong here.";
    2:
     self.each_turn = NULL; move ladder to location;
     "^Suddenly, you see a ladder appear, leading down.";
   }
  ],
  number 0,
  d_to
  [;
   if (self.number < 2)
    "You can't go that way.";
   else return CompassRoom;
  ],
 has light;

Object ladder "ladder"
 with
  name 'ladder',
  description "A simple wood ladder, leading down.",
 has static scenery;

Object CompassRoom "(nowhere)"
 with
  description "What?",
  before
  [ a;
   What:
    print "whatwhatwhatwhatwhatwhatwhatwhatwhatwhatwhatwhatwhatwhatw[Press any
     key to exit.]";
    @read_char 1 0 0 a;
    @erase_window NULL;
    print "^^^^Aaah. Much better.^^";
    score = score + 5;
    PlayerTo(realroom, 0); rtrue;
   default: "What?";
  ],
 has light;

Object realroom "Nondescript room"
 with
  description "A small, nondescript room with exits in all directions.",
  n_to RoomOfLies,
  cant_go "As you bump into the wall, you can't help but curse the person
   who so maliciously painted the doorway onto it.",
  has light;

Object RoomOfLies "Room Of Truth"
 with
  short_name
  [;
   if (self.number == 0) "Room Of Truth";
   "Room of Lies";
  ],
  description
  [;
   if (self.number == 0) "This room will always tell you the truth. Trust me. 
      No, really. You can see lots and lots of weird machinery here.";
   else if (note notin location or player)
   {
     move note to location;
     "Okay, so I lied. Well, this ain't the Room Of Truth, either.
      It's only yet another small cubicle; a note lies on the ground.";
   }
   else "It's only yet another small cubicle.";
  ],
  each_turn
  [;
   self.number++;
   if (self.number == 10)
   {
    deadflag = 3;
    "Suddenly, you hear a hammering sound coming from one wall. Only seconds
     later, it breaks, and in stream your relatives! They as quickly disappear
     through the east wall (which turns out to be made of paper), and you
     hear their excited cries as they bathe in your uncle's immeasurable
     riches!^^
     Damn.";
   }
  ],
  number 0,
  s_to "The exit has closed behind you.",
  cant_go "You can go that way.",
  e_to
  [;
   if (self hasnt general)
   {
    give self general;
    "You can't walk through walls.";
   }
   deadflag = 2; score = score + 15;
   "You try to walk through the wall anyway, and notice it's only made of
    paper! Beyond it you see the treasure vault of your uncle, filled with
    immeasurable riches! Only seconds later, your relatives storm in - but
    you have beaten them!^^Good old Uncle Soandso.";
  ],
 has light;

Object -> machinery "machinery"
 with
  name 'weird' 'strange' 'machinery' 'gadgetry' 'stuff' 'things//p',
  description "Hey! The room lied! You can't see any machinery here.",
  before
  [;
   default:
    print "Hey! The room lied! You can't see any machinery here!^";
    <<Look>>;
  ],
 has static scenery;

Object note "note"
 with
  name 'note' 'piece' 'paper' 'white',
  description "It says:^^
   ~So, you thought you would get my treasure, eh? Well, you don't. And there's
   no way of getting out of here, either. HA!^^
   Uncle Soandso.~^^What a jerk.";

[ Initialise;
 location = BlankRoom; turns = 1020; score = 580;
 "^^^^Finally, you have reached the end of this maze, a maze which kept you
  wandering about for the last five hundred turns. Your mad uncle's
  treasure chamber stretches before you. TIME TO...^^^";
];

[ Amusing;
 "For those who actually expected a serious entry from me, sorry. I can't
  resist doing stupid games. But it's lot of fun to compose those quickies;
  maybe I'll even do so for the regular competition :-)^^
  Then again, maybe not.^^
  Thanks to Liza Daly and Dan Shiovitz for testing...^^
  Thank YOU for playing this Micro-Comp entry!";
];

[ WhatSub;
 "What what?";
];

[ XyzzySub;
 "A hollow voice says, ~Chicken!~";
];

[ DeathMessage;
 print "You have lost the treasure.";
];

Include "Grammar";

Verb 'what' 'what?' * -> What;

Verb 'xyzzy'        * -> Xyzzy;

end;